Flash

在ActionScript 3.0之前的Event Model，簡單來說就像是個各自為政的Model，若是硬要評比的話~好處是簡單易用、彈性大~而壞處是沒有統一的Event Model，容易造成學習者混淆~尤其是當一些小細節被忽略時，往往深埋著不定時炸彈，所以在事件的處理上，了解並掌握它是不可或缺的~

「onClipEvent」and「MovieClip.onXXX」執行的優先權

我們建立一個MovieClip在Stage上，並將它命名為「a_mc」，並在此MovieClip上加些程式以便驗證。

onClipEvent(load)
{
	trace("a_mc(load):"+this);
}

然而在MainTimeline也寫入下述程式：

a_mc.onLoad = function()
{
	trace("a_mc(onLoad):"+this);
}
trace("frame[1]");

然後在此MovieClip的Frame[1]也加上：

trace("a_mc(frame[1]):"+this);

最後一樣「Ctrl + Enter」來看結果：

frame[1]
a_mc(load):_level0.a_mc
a_mc(onLoad):_level0.a_mc
a_mc(frame[1]):_level0.a_mc

從結果來看就可以證明「onClipEvent」的執行優先權比「MovieClip.onXXX」來的高!

範例下載

我們來看一下簡單的例子~

假設我們放一個MovieClip在Stage上，並在此MovieClip下點程式，讓它能夠隨著播放時進行旋轉~

以下均發佈成Flash Player 8 & ActionScript 2.0的swf file

程式一

onClipEvent (enterFrame)
{
    this._rotation += 5;
}

程式一ActionCode

onClipEvent (enterFrame)
{
	ActionConstantPool "this" "_rotation"
	ActionPush "this"
	ActionGetVariable
	ActionPush "_rotation" "this"
	ActionGetVariable
	ActionPush "_rotation"
	ActionGetMember
	ActionPush 5
	ActionAdd2
	ActionSetMember
	ActionEndFlag
}

程式一的ActionCode是最多的一個，我們再試著將「this」移掉試試：

程式二

onClipEvent (enterFrame)
{
    _rotation += 5;
}

程式二ActionCode

onClipEvent (enterFrame)
{
	ActionConstantPool ""
	ActionPush "" 10 "" 10
	ActionGetProperty
	ActionPush 5
	ActionAdd2
	ActionSetProperty
	ActionEndFlag
}

從上述的ActionCode可以發現精簡了不少，其實我們可以發現它相當於如下列的程式：

onClipEvent (enterFrame)
{
    setProperty("", _rotation, _rotation + 5);
}

最後我們再試著將「this」取代「double-quote」，如程式三：

程式三

onClipEvent (enterFrame)
{
    setProperty(this, _rotation, _rotation + 5);
}

程式三ActionCode

onClipEvent (enterFrame)
{
	ActionPush "this"
	ActionGetVariable
	ActionPush 10 "" 10
	ActionGetProperty
	ActionPush 5
	ActionAdd2
	ActionSetProperty
	ActionEndFlag
}

從上述三個程式的ActionCode數量來看~ 若是硬要雞蛋裡挑骨頭的話，程式二在執行上應該是有較佳的效率，純屬從結果上來推論~

Flex.org 提供的海報下載~

ActionScript 3 API

Flex 2 Framework API

以往要載入一個外部的XML檔案的話，我們可以簡化成下列的作法：

Loading XML

var externalXML:XML = new XML();
externalXML.onLoad = function(success)
{
    trace(externalXML);
};
externalXML.load("myxml.xml");

從載入方式到Callback Event的處理，完全交由「XML」類別來孤軍奮戰~

然而ActionScript 3.0，它終於多了幾位幫手來協助它了~ 不僅減輕它的負擔，也能夠各司其職~

Loading XML for AS 3.0

var externalXML:XML;
var loader:URLLoader = new URLLoader();
var request:URLRequest = new URLRequest("myxml.xml");
loader.load(request);
loader.addEventListener(Event.COMPLETE, onComplete);
loader.addEventListener(ProgressEvent.PROGRESS, onProgress);

function onComplete(event:Event):void
{
	externalXML = new XML(event.target.data);
	trace(externalXML.toXMLString());
}
function onProgress(event:ProgressEvent):void
{	
	trace(event.bytesLoaded);
	trace(event.bytesTotal);
}

我們可以發現載入方式完全交由「URLLoader」去處理，Callback Event也委託「IEventDispatcher」來負責，最重要的是~ 這樣的作法才符合 High Cohesion and Low Coupling，大大地增強其彈性~

而且ActionScript 3.0是以ECMAScript for XML (E4X) specification (ECMA-357 edition 2)為基礎來處理XML資料，不僅更容易使用也更簡化操作~ 順便看一下例子：

var myXML:XML =
<order>
	<item id='1'>
		<menuName>burger</menuName>
		<price>3.95</price>
	</item>
	<item id='2'>
		<menuName>fries</menuName>
		<price>1.45</price>
	</item>
</order>

trace(myXML.item[0].menuName); // Output: burger
trace(myXML.item.(@id==2).menuName); // Output: fries
trace(myXML.item.(menuName=="burger").price); // Output: 3.95

果然夠簡化與方便!!!

可用來將影像模糊化~ Try it!

Blur

import flash.display.BitmapData;
function Blur():Void
{
	var myBitmapData:BitmapData = BitmapData.loadBitmap("brg");
	var height:Number = myBitmapData.height;
	var width:Number = myBitmapData.width;

	var gray:Array = new Array(width);

	for(var i:Number = 0 ; i < width ; i++)
		gray[i] = new Array(height);
		
	var gray2:Array = new Array(width);

	for(var i:Number = 0 ; i < width ; i++)
		gray2[i] = new Array(height);

	//RGB to GRAY
	for(var i:Number = 0 ; i < width ; i++)
	{
		for(var j:Number = 0 ; j < height ; j++)
		{
			var rgb:Number = myBitmapData.getPixel(i,j);
			var r:Number = 0xFF&(rgb >> 16);
			var g:Number = 0xFF&(rgb >> 8);
			var b:Number = 0xFF&rgb;			
			gray[i][j]= 0.299*r + 0.587*g +0.114*b;
		}
	}
	
	for(var x = 1; x < width-1;x++)
	{
		for(var y = 1; y < height-1;y++)
		{
			/**
			 00(a) 10(b) 20(c)
			 01(d) 11(*) 21(e)
			 02(f) 12(g) 22(h)
			*/
			var a = gray[x-1][y-1]*0.1;
			var b = gray[x][y-1]*0.1;
			var c = gray[x+1][y-1]*0.1;
			var d = gray[x-1][y]*0.1;
			var e = gray[x][y]*0.1;
			var f = gray[x+1][y]*0.1;
			var g = gray[x-1][y+1]*0.1;
			var h = gray[x][y+1]*0.1;
			var i = gray[x+1][y+1]*0.1;
			
			var gc = (a+b+c+d+e+f+g+h+i);
			
			gray2[x][y] = 0xff000000  |gc<<16 | gc<<8 | gc;
		}
	}
	
	//set pixel value
	for(var i:Number = 0 ; i < width ; i++)
	{
		for(var j:Number = 0 ; j < height ; j++)
		{
				
			myBitmapData.setPixel(i,j,gray2[i][j]);
		}
	}

	var mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
	mc.attachBitmap(myBitmapData,this.getNextHighestDepth());
}
Blur();